DbBackup/DbValidate

Met het programma DbBackup.exe kun je een backup maken van de King-administraties buiten King om. Dat kan ook als die administratie op dat moment in gebruik is. Via een batch-file kan de gebruiker dan op een vast tijdstip (via scheduled tasks, standaard in Windows) een live backup maken. Met het programma DbValidate.exe kun je administraties valideren buiten King om. Dat programma is op dezelfde manier aan te sturen als DbBackup.exe.

Valideren

Het is raadzaam om de administratie te controleren/valideren voordat er een backup wordt gemaakt. Dit kan met het volgende commando :

DbValid -c "uid=KingBackup;pwd=KingBackup;dbf= D:\Databases\DemoArt.db;eng=xxxx;dbs=-n xxxx"

De belangrijkste parameters:

  • -c uid=KingBackup;pwd=KingBackup;, bij het valideren wordt gebruik gemaakt van een speciale King-gebruiker met de code KingBackup en het wachtwoord KingBackup. Deze gebruiker is niet zichtbaar in King;
  • dbf= D:\Databases\DemoArt.db;, de bestandslocatie en de bestandsnaam van de administratie die je wilt valideren;
  • eng=xxxx;dbs=-n xxxx, vervang xxxx bij een client-server installatie door “King-Server” en in een standalone situatie door “King_546a_” + pcnaam (bijv. “King_546a_Naam_PC”). Als in de pc-naan een “-“ voorkomt, dan wordt deze vervangen door “_”;

Bij het valideren wordt de volgende waarschuwing gegeven:

“WARNING: database being validated was not started read-only”

Deze kan genegeerd worden.

Backup maken

Met het volgende commando kun je een backup maken:

DbBackup.exe –d –x –y -c "uid=KingBackup;pwd=KingBackup;dbf=D:\Databases\DemoArt.db;eng=xxxx" “C:\Backup”

De belangrijkste parameters:

  • -d, maakt alleen een backup van het db-bestand;
  • -x, verwijdert het log-bestand en maakt een nieuw log-bestand aan;
  • -y, vervangt bestanden zonder om bevestiging te vragen;
  • -c uid=KingBackup;pwd=KingBackup;, bij het valideren wordt gebruik gemaakt van een speciale King-gebruiker met de code KingBackup en het wachtwoord KingBackup. Deze gebruiker is niet zichtbaar in King;
  • dbf= D:\Databases\DemoArt.db;, de bestandslocatie en de bestandsnaam van de administratie die je wilt valideren;
  • eng=xxxx, vervang xxxx bij een client-server installatie door “King-Server” en in een standalone situatie door “King_546a_” + pcnaam (bijv. “King_546a_Naam_PC”). Als in de pc-naan een “-“ voorkomt, dan wordt deze vervangen door “_”;
  • “C:\Backup”, de locatie waar de backup gemaakt wordt.

Voorbeeld van een batchbestand

@echo off
REM Database inclusief pad waar een backup van moet worden gemaakt
set Dbf=C:\Quadrant\King\Data\demoart.db
REM Pad waar de backup moet komen
set BackupFolder=C:\
REM Naam van database-engine, "King5_46a_"+Pcnaam (waarbij een mogelijk "-" vervangen is door "_")
set DbServer=King5_45a_WORKER_001
REM Controleer of de database gevonden kan worden
if exist %Dbf% goto BackupFolder
echo.
echo DATABASE %Dbf% NIET GEVONDEN!
goto Einde
:BackupFolder
REM Controleer of backupfolder bestaat
if exist %BackupFolder% goto Validate
echo.
echo BACKUPFOLDER %BackupFolder% BESTAAT NIET OF NIET VOLDOENDE RECHTEN!
goto Einde
:Validate
REM Controleer de database op fouten
DbValid -c "uid=KingBackup;pwd=KingBackup;dbf=%Dbf%;eng=%DbServer%"
if %errorlevel% == 0 goto Backup
echo.
echo ER IS EEN FOUT ONTSTAAN TIJDENS HET CONTROLEREN VAN DE ADMINISTRATIE!
echo.
echo ER IS GEEN BACKUP GEMAAKT!
goto Einde
:Backup
REM Maak een backup van de database
DbBackup -d -x -y -c "uid=KingBackup;pwd=KingBackup;dbf=%Dbf%;eng=%DbServer%" %BackupFolder%
if %errorlevel% == 0 goto Einde
echo.
echo ER IS EEN FOUT ONTSTAAN TIJDENS HET MAKEN VAN DE BACKUP VAN DE ADMINISTRATIE!
echo.
echo ER IS GEEN BACKUP GEMAAKT!
:Einde
echo.

 

Koppelingspictogram voor conceptenZie ook